Alouette Reservoir Kokanee Population Analysis 2015

Data Preparation

The hydroacoustic and gillnetting data from 1998-2014 on the Alouette Reservoir were provided by Redfish Consulting Ltd.(G. Andrusak) and BC MNFLRO (S. Harris).

Statistical Analysis

Hierarchical Bayesian models were fitted to the count data using R version 3.2.3 (Team 2013) and JAGS 4.0.1 (Plummer 2015) which interfaced with each other via jaggernaut 2.3.1 (Thorley 2013). For additional information on hierarchical Bayesian modelling in the BUGS language, of which JAGS uses a dialect, the reader is referred to (Kery and Schaub 2011, 41–44).

Unless specified, the models assumed vague (low information) prior distributions (Kery and Schaub 2011, 36). The posterior distributions were estimated from a minimum of 1,000 Markov Chain Monte Carlo (MCMC) samples thinned from the second halves of three chains (Kery and Schaub 2011, 38–40). Model convergence was confirmed by ensuring that Rhat (Kery and Schaub 2011, 40) was less than 1.1 for each of the parameters in the model (Kery and Schaub 2011, 61).

The posterior distributions of the fixed (Kery and Schaub 2011, 75) parameters are summarised in terms of a point estimate (mean), lower and upper 95% credible limits (2.5th and 97.5th percentiles), the standard deviation (SD), percent relative error (half the 95% credible interval as a percent of the point estimate) and significance (Kery and Schaub 2011, 37, 42).

Variable selection was achieved by dropping insignificant (Kery and Schaub 2011, 37, 42) fixed (Kery and Schaub 2011, 77–82) variables and uninformative random variables. A fixed variables was considered to be insignificant if its significance was \(\geq\) 0.05 while a random variable was considered to be uninformative if its percent relative error was \(\geq\) 80%. The Deviance Information Criterion (DIC) was not used because it is of questionable validity when applied to hierarchical models (Kery and Schaub 2011, 469).

The results are displayed graphically by plotting the modelled relationships between particular variables and the response with 95% credible intervals (CRIs) with the remaining variables held constant. In general, continuous and discrete fixed variables are held constant at their mean and first level values respectively while random variables are held constant at their typical values (expected values of the underlying hyperdistributions) (Kery and Schaub 2011, 77–82). Where informative the influence of particular variables is expressed in terms of the effect size (i.e., percent change in the response variable) with 95% CRIs (Bradford, Korman, and Higgins 2005).

Model Code

The JAGS model code, which uses a series of naming conventions, is presented below.

model{
  bLength ~ dnorm(5, 5^-2)

  bLengthDayte ~ dnorm(0, 5^-2)

  bLengthProductivity ~ dnorm(0, 5^-2)

  sLengthYear ~ dunif(0, 5)
  for (i in 1:nYear) {
      bLengthYear[i] ~ dnorm(0, sLengthYear^-2)
  }

  sLengthLocationYear ~ dunif(0, 5)
  for (i in 1:nLocation) {
    for(j in 1:nYear) {
      bLengthLocationYear[i, j] ~ dnorm(0, sLengthLocationYear^-2)
    }
  }

  sLength ~ dunif(0, 5)

  for(i in 1:length(Length)){
    log(eLength[i]) <- bLength
                     + bLengthDayte * Dayte[i]
                     + bLengthProductivity * Productivity[i]
                     + bLengthYear[Year[i]]
                     + bLengthLocationYear[Location[i], Year[i]]

    Length[i] ~ dlnorm(log(eLength[i]), sLength^-2)
  }
}

model {
  K ~ dnorm(10^3, (10^3 /2)^-2) T(1, )
  R0 ~  dnorm(10^5, (10^5)^-2) T(10^4, 10^7)

  bElevationalDrop ~ dnorm(0, 5^-2)

  sRecruits ~ dunif(0, 5)

  for(i in 1:length(Stock)){
    log(eRecruits[i]) <- log(K * Stock[i] / (1 + Stock[i] * (K - 1) / R0))
                       + bElevationalDrop * ElevationalDrop[i]

    Recruits[i] ~ dlnorm(log(eRecruits[i]), sRecruits^-2)
  }
}

model {
  K ~ dnorm(2, 1^-2) T(1, )
  R0 ~  dnorm(10^4, (10^3)^-2) T(0, )

  bElevationalDrop ~ dnorm(0, 5^-2)

  sRecruits ~ dunif(0, 5)

  for(i in 1:length(Stock)){
    log(eRecruits[i]) <- log(K * Stock[i] / (1 + Stock[i] * (K - 1) / R0))
                       + bElevationalDrop * ElevationalDrop[i]

    Recruits[i] ~ dlnorm(log(eRecruits[i]), sRecruits^-2)
  }
}

Model Parameters

The posterior distributions for the fixed (Kery and Schaub 2011 p. 75) parameters in each model are summarised below.

Figures

Reservoir Operations

Abundance

Size-At-Age

Spawners To Fry

Fry To Age-1