Lardeau-Lower Duncan River Age-1 Rainbow Trout Abundance and Stock-Recruitment Analysis 2015

Length-Bias Correction

Biases in length estimation were estimated manually; for each observer for each unique day of observations, a fork-length cut-off between age-1 and age-2+ Rainbow Trout was estimated, which was then used to classify each fish by lifestage.

Observer Efficiency

The observer efficiency for age-1 Rainbow Trout was estimated using a mark-resight binomial model (Kery and Schaub 2011, 134–36, 384–88).

Key assumptions of the observer efficiency model include:

• The observer probability varies with study design (Index versus GPS).
• There is no tag loss.
• There is no emigration of marked fish.
• The number of marked fish that are resighted is described by a binomial distribution.

Useable width and swimmer were not found to be significant or informative predictors of observer efficiency, respectively.

Abundance

The abundance was estimated from the bias-corrected observer count data using an overdispersed Poisson model (Kery and Schaub 2011, 55–56). The annual abundance estimates represent the total number of fish in the study area.

Key assumptions of the abundance model include:

• The lineal fish density varies with year, useable width and river kilometer as a polynomial, and randomly with site.
• The observer efficiency at marked sites was as estimated by the observer efficiency model (which varied by study design).
• The observer efficiency also varies with visit type (standard count versus presence of marked fish) within study design, and randomly with swimmer.
• The expected count at a site is the expected lineal density multiplied by the site length, the observer efficiency and the proportion of the site surveyed.
• The residual variation in the actual count is gamma-Poisson distributed.

Curvature and channel class were not found to be significant predictors of density.

Stock-Recruitment

The relationship between the number of Rainbow Trout spawners in a given year (\(S\)) and the number of age-1 Rainbow Trout the following spring (\(R\)) was estimated using the smooth hockey stick stock-recuitment model (Froese 2008):

\[ R = R_\infty \cdot \left(1 - \exp{\left\{-\frac{\alpha}{R_\infty} \cdot S\right\}} \right) \quad,\]

where \(R_\infty\) is the carrying capacity of recruits, and \(\alpha\) is the number of recruits per spawner at low density.

Key assumptions of the stock-recruitment model include:

• The prior probability \(\alpha\) is normally distributed with a mean of 500 and a SD of 250; this mean is based on an average of 8,000 eggs per female spawner, a 50:50 sex ratio, 50% egg survival, 50% post-emergence fall survival and 50% overwintering survival.
• The residual variation in the number of recruits is log-normally distributed.

The Q90 discharge in July and the Q10 discharge from January to February were not found to be significant predictors of \(R_\infty\).

Escapement

The number of spawners required to reach a given percentage the recruit carrying capacity (\(\epsilon = R/R_\infty\)) was estimated from the hockey stick stock-recuitment model using the equation:

\[ S = \frac{R_\infty}{\alpha} \cdot \ln{\left(1 - \epsilon\right)^{-1}} \quad. \]

Capture Efficiency

model{

  bEfficiency ~ dnorm(0, 5^-2)

  bEfficiencyStudyDesign[1] <- 0
  for (ii in 2:nStudyDesign) {
    bEfficiencyStudyDesign[ii] ~ dnorm(0, 2^-2)
  }

  for(ii in 1:length(Marked)){
    logit(eEfficiency[ii]) <- bEfficiency
                            + bEfficiencyStudyDesign[StudyDesign[ii]]

    Resighted[ii] ~ dbin(eEfficiency[ii], Marked[ii])
  }
}

Abundance

model{

  for(yr in 1:nYear){
    bDensityYear[yr] ~ dnorm(0, 5^-2)
  }

  bDensityWidth ~ dnorm(0, 2^-2)

  sDensitySite ~ dunif(0, 5)
  for(st in 1:nSite){
    bDensitySite[st] ~ dnorm(-sDensitySite^2 / 2, sDensitySite^-2)
  }

  bDensityMarking[1] <- 0
  for(mk in 2:nMarking) {
    bDensityMarking[mk] ~ dnorm(0, 5^-2)
  }

  sEfficiencySwimmer ~ dunif(0, 5)
  for(sw in 1:nSwimmer){
    bEfficiencySwimmer[sw] ~ dnorm(0, sEfficiencySwimmer^-2)
  }

  bDensityRkm1 ~ dnorm(0, 2^-2)
  bDensityRkm2 ~ dnorm(0, 2^-2)
  bDensityRkm3 ~ dnorm(0, 2^-2)
  bDensityRkm4 ~ dnorm(0, 2^-2)

  for(sd in 1:nStudyDesign){
    bEfficiencyStudy[sd] ~ dnorm(Efficiency[sd], Efficiency.sd[sd]^-2) T(Efficiency.lower[sd], Efficiency.upper[sd])
  }

  for(sd in 1:nStudyDesign){
    bEfficiencyVisitStudy[1, sd] <- 0
    for(vt in 2:nVisitType){
      bEfficiencyVisitStudy[vt, sd] ~ dnorm(0, 2^-2)
    }
  }

  sDispersion ~ dunif(0, 5)

  for(ii in 1:length(Count)){
    log(eDensity[ii]) <- bDensityYear[Year[ii]]
                       + bDensityWidth * log(Width[ii])
                       + bDensitySite[Site[ii]]
                       + bDensityRkm1 * Rkm[ii]
                       + bDensityRkm2 * Rkm[ii]^2
                       + bDensityRkm3 * Rkm[ii]^3
                       + bDensityRkm4 * Rkm[ii]^4
                       + bDensityMarking[Marking[ii]]

    eAbundance[ii] <- eDensity[ii] * SiteLength[ii]

    logit(eEfficiency[ii]) <- logit(bEfficiencyStudy[StudyDesign[ii]])
                            + bEfficiencyVisitStudy[VisitType[ii], StudyDesign[ii]]
                            + bEfficiencySwimmer[Swimmer[ii]]

    eCount[ii] <- eAbundance[ii] * eEfficiency[ii] * SurveyProportion[ii]

    eDispersion[ii] ~ dgamma(1/sDispersion^2, 1/sDispersion^2)

    Count[ii] ~ dpois(eCount[ii] * eDispersion[ii])
  }
}

Stock-Recruitment

model{

  alpha ~ dnorm(8000 * 0.5^4, 250^-2) T(0,)
  Rinf ~ dunif(5 * 10^4, 2.5 * 10^5)

  sRecruits ~ dunif(0, 5)
  for (ii in 1:length(Spawners)) {
    eRecruits[ii] <- Rinf * (1 - exp(-alpha / Rinf *  Spawners[ii]))
    Recruits[ii] ~ dlnorm(log(eRecruits[ii]) - sRecruits^2 / 2, sRecruits^-2)
  }
}

Escapement

model{

  bRinf ~ dnorm(Rinf.mean, Rinf.sd^-2) T(Rinf.lower, Rinf.upper)
  bAlpha ~ dnorm(alpha.mean, alpha.sd^-2) T(alpha.lower, alpha.upper)

  bS0 <- bRinf/bAlpha
}

Capture Efficiency - Age-1

Abundance - Age-1

Stock-Recruitment

Escapement

Capture Efficiency - Age-1

Abundance - Age-1

Stock-Recruitment

Escapement