Elk River WCT Abundance Analysis 2023

Growth

Annual growth was estimated with measurement error from the inter-annual PIT tag recaptures using the Fabens method (Fabens 1965) for estimating the von Bertalanffy growth curve (von Bertalanffy 1938). This curve is based on the premise that:

\[ \frac{\text{d}L}{\text{d}t} = k (L_{\infty} - L)\]

where \(L\) is the length of the individual, \(k\) is the growth coefficient and \(L_{\infty}\) is the maximum length.

Integrating the above equation gives:

\[ L_t = L_{\infty} (1 - e^{-k(t - t_0)})\]

where \(L_t\) is the length at time \(t\) and \(t_0\) is the time at which the individual would have had zero length.

The Fabens form allows

\[ L_r = L_c + (L_{\infty} - L_c) (1 - e^{-kT})\]

where \(L_r\) is the length at recapture, \(L_c\) is the length at capture and \(T\) is the time between capture and recapture.

Measurement error was incorporated by using additional variation around the reported fork length measurements to estimate the true lengths for initial captures and recaptures, which were used to estimate the growth model parameters.

Nine fish with very unlikely reported growth increments (as determined by an absolute deviance residual greater than two) were excluded from the final analysis.

Key assumptions of the growth model include:

• The standard deviation of measurement error varies by capture group (guides versus electrofishing) and year.
• The standard deviation of measurement error varies randomly by capture group within year.
• The residual variation in measurement error is normally distributed.
• The residual variation in growth is normally distributed.

Capture Efficiency

The data were analysed using a logistic regression model. Guide captures were excluded from this analysis because their sampling effort is unknown.

Key assumptions of the efficiency model include:

• Capture efficiency varies by year, electrofishing effort, and fork length and its squared polynomial.
• There is an increasing asymptotic relationship between electrofishing effort and capture efficiency.
• The residual variation in whether or not a capture was a within-year recapture is Bernoulli-distributed.

Movement

The extent to which sites are closed (i.e., fish remain at the same site within a sampling season) was evaluated using a logistic regression model. The model estimates the probability that intra-annual recaptures were caught at the same site versus a different one.

Key assumptions of the site fidelity model include:

• The probability of site fidelity varies by fork length.
• The residual variation in site fidelity is Bernoulli-distributed.

Annual Abundance

The data were analysed using a hierarchical Bayesian mark-recapture abundance model. Each zone was split into six kilometre sites, except sites at the end of the zone, which were added to the previous site if the length was less than three kilometres. Captures from sites that had less then 10% of their length surveyed were not included in the analysis.

Fish were divided into two length classes based on the estimated relationship between fork length and capture efficiency. The fish were split into length classes using their mean estimated true length in the year of capture if they were ever recaptured, based on the growth model, and their reported length if they were not recaptured. The small class includes fish between 200 and 299 mm, and the large class includes fish 300 mm and greater. 142 fish under 200 mm, as well as 7 fish missing length measurements were excluded from this analysis.

Key assumptions of the mark-recapture abundance model include:

• 61% of previously marked fish are present at a site when it is resampled.
• There is no mortality of fish within a sampling season.
• The probability of capturing a marked or unmarked fish is the same.
• All recaptured fish are correctly identified as being marked and there is no tag loss.
• Lineal densities of small fish vary randomly by year and site within year.
• Lineal densities of large fish vary randomly by year and site within year.
• Capture efficiency varies by electrofishing effort.
• The effect of electrofishing effort is the same for small and large fish.
• Capture efficiency of small fish varies randomly by site visit.
• Capture efficiency of large fish varies randomly by site visit.
• The number of small and large recaptures (of fish marked at that site in that year) and the total number of small and large fish caught are each binomially distributed.

Annual Survival

Preliminary analysis found that the data were insufficient to reliably determine whether non-captures were due to mortality, failure to recapture, or movement out of the study area.

Growth

. model{
    bK ~ dbeta(1, 1)
    bLinf ~ dnorm(400, 100^-2) T(0,)
    bErrorIntercept ~ dnorm(0, 2^-2)
    bErrorGroup[1] <- 0
    for (i in 2:ngroup) {
      bErrorGroup[i] ~ dnorm(0, 2^-2)
    }
    bErrorAnnual[1] <- 0
    for (i in 2:nannual) {
      bErrorAnnual[i] ~ dnorm(0, 2^-2)
    }
    sErrorGroupAnnual ~ dexp(1)
    for (i in 1:ngroup) {
      for (j in 1:nannual) {
        bErrorGroupAnnual[i, j] ~ dnorm(0, sErrorGroupAnnual^-2)
      }
    }

    for (i in 1:nfish_id) {
      bTrueInitialLength[i] ~ dnorm(300, 100^-2) T(0, 600)
      log(eObsInit[i]) = bErrorIntercept + bErrorGroup[initial_group[i]] + bErrorAnnual[initial_annual[i]] + bErrorGroupAnnual[initial_group[i], initial_annual[i]]
      obs_initial_length[i] ~ dnorm(bTrueInitialLength[i], eObsInit[i]^-2)
    }

    for (i in 1:nObs) {
      log(eObsRecap[i]) = bErrorIntercept + bErrorGroup[group[i]] + bErrorAnnual[annual[i]] + bErrorGroupAnnual[group[i], annual[i]]
      eGrowth[i] = (bLinf - bTrueInitialLength[fish_id[i]]) * (1 - exp(-bK * years[i]))
      eTrueFinalLength[i] = ifelse(eGrowth[i] < 0, bTrueInitialLength[fish_id[i]], bTrueInitialLength[fish_id[i]] + eGrowth[i])
      recapture_length[i] ~ dnorm(eTrueFinalLength[i], eObsRecap[i]^-2)
    }
  }

Block 1. Model description.

Capture Efficiency

.model {
  bEfficiencyEffort ~ dnorm(0, 2^-2)
  bEfficiencyLength ~ dnorm(0, 2^-2)
  bEfficiencyLength2 ~ dnorm(0, 2^-2)

  for (i in 1:nannual) {
    bEfficiencyAnnual[i] ~ dnorm(-3, 10^-2)
  }
  for (i in 1:nObs){
    logit(eEfficiency[i]) <- bEfficiencyAnnual[annual[i]] + bEfficiencyEffort * (log(effort[i]) - log(0.25)) + bEfficiencyLength * length[i] + bEfficiencyLength2 * length[i]^2
    recapture[i] ~ dbern(eEfficiency[i])
  }

Block 2. Model description.

Movement

.model{
  bFidelity ~ dnorm(0, 2^-2)
  bLength ~ dnorm(0, 2^-2)

  for (i in 1:nObs) {
    logit(eFidelity[i]) <- bFidelity + bLength * fork_length[i]
    fidelity[i] ~ dbern(eFidelity[i])
  }

Block 3. Model description.

Annual Abundance

.model{
  sDensitySmallAnnualSiteID ~ dexp(1)
  sDensityLargeAnnualSiteID ~ dexp(1)
  for (i in 1:nannual) {
    bEfficiencySmallAnnual[i] ~ dnorm(-4, 2^-2)
    bEfficiencyLargeAnnual[i] ~ dnorm(-4, 2^-2)
    bDensitySmallAnnual[i] ~ dnorm(5, 2^-2)
    bDensityLargeAnnual[i] ~ dnorm(5, 2^-2)
    for (j in 1:nsite_id) {
      bDensitySmallAnnualSiteID[i, j] ~ dnorm(0, sDensitySmallAnnualSiteID^-2)
      bDensityLargeAnnualSiteID[i, j] ~ dnorm(0, sDensityLargeAnnualSiteID^-2)
    }
  }
  bFidelity ~ dbeta(33, 21)
  bEfficiencySecondsPerMetre ~ dnorm(0, 1^-2)
  bThetaLarge ~ dexp(10)
  bThetaSmall ~ dexp(10)

  for (i in 1:nObs) {
    log(eDensitySmall[i]) <- bDensitySmallAnnual[annual[i]] + bDensitySmallAnnualSiteID[annual[i], site_id[i]]
    logit(eProbSmall[i]) <- bEfficiencySmallAnnual[annual[i]] + bEfficiencySecondsPerMetre * seconds_per_metre[i]
    eEfficiencySmall[i] ~ dbeta((2 * eProbSmall[i]) / bThetaSmall, (2 * (1 - eProbSmall[i])) / bThetaSmall)
    recaptures_small[i] ~ dbinom(eEfficiencySmall[i] * bFidelity, marked_small[i])
    bAbundanceSmall[i] ~ dpois(eDensitySmall[i] * site_length[i] * survey_proportion[i])
    count_small[i] ~ dbinom(eEfficiencySmall[i], bAbundanceSmall[i])
  }
  for (i in 1:nObs) {
    log(eDensityLarge[i]) <- bDensityLargeAnnual[annual[i]] + bDensityLargeAnnualSiteID[annual[i], site_id[i]]
    logit(eProbLarge[i]) <- bEfficiencyLargeAnnual[annual[i]] + bEfficiencySecondsPerMetre * seconds_per_metre[i]
    eEfficiencyLarge[i] ~ dbeta((2 * eProbLarge[i]) / bThetaLarge, (2 * (1 - eProbLarge[i])) / bThetaLarge)
    recaptures_large[i] ~ dbinom(eEfficiencyLarge[i] * bFidelity, marked_large[i])
    bAbundanceLarge[i] ~ dpois(eDensityLarge[i] * site_length[i] * survey_proportion[i])
    count_large[i] ~ dbinom(eEfficiencyLarge[i], bAbundanceLarge[i])
  }

Block 4. Model description.

Growth

Table 1. Parameter descriptions.

Table 2. Model coefficients.

Table 3. Model convergence.

Table 4. Model posterior predictive checks.

Table 5. Model sensitivity.

Capture Efficiency

Table 6. Parameter descriptions.

Table 7. Model coefficients.

Table 8. Model convergence.

Table 9. Model posterior predictive checks.

Table 10. Model sensitivity.

Movement

Table 11. Parameter descriptions.

Table 12. Model coefficients.

Table 13. Model convergence.

Table 14. Model posterior predictive checks.

Table 15. Model sensitivity.

Annual Abundance

Table 16. Parameter descriptions.

Table 17. Model coefficients.

Table 18. Model convergence.

Table 19. Model posterior predictive checks.

Table 20. Model sensitivity.

Table 21. The estimated abundance in zones 2 to 6 of the Elk River, by year and size class (with 95% CIs).

PIT Tags

Table 22. The number of tags deployed and tags recaptured by year and by method.

Maps

Size

Captures

Growth

Capture Efficiency

Movement

Annual Abundance

Outing

Codes

Floy Tags