Duncan Lardeau Juvenile Rainbow Trout Abundance 2018

Data Preparation

The data were provided by the Ministry of Forests, Lands and Natural Resource Operations (MFLNRO). The historical and current snorkel count data were manipulated using R version 3.5.1 (R Core Team 2017) and organised in an SQLite database.

Data Analysis

Hierarchical Bayesian models were fitted to the data using R version 3.5.1 (R Core Team 2017), Stan 2.16.0 (Carpenter et al. 2017) and JAGS 4.2.0 (Plummer 2015) and the mbr family of packages.

Unless indicated otherwise, the models used prior distributions that were vague in the sense that they did not affect the posterior distributions (Kery and Schaub 2011, 36). The posterior distributions were estimated from 2,000 Markov Chain Monte Carlo (MCMC) samples thinned from the second halves of three chains (Kery and Schaub 2011, 38–40). Model convergence was confirmed by ensuring that \(\hat{R} < 1.1\) (Kery and Schaub 2011, 40) for each of the monitored parameters in the model (Kery and Schaub 2011, 61). Where relevant, model adequacy was confirmed by examination of residual plots.

The posterior distributions of the fixed (Kery and Schaub 2011, 75) parameters are summarised in terms of the point estimate, standard deviation (sd), the z-score, lower and upper 95% confidence/credible limits (CLs) and the p-value (Kery and Schaub 2011, 37, 42). The estimate is the median (50th percentile) of the MCMC samples, the z-score is \(\mathrm{mean}/\mathrm{sd}\) and the 95% CLs are the 2.5th and 97.5th percentiles. A p-value of 0.05 indicates that the lower or upper 95% CL is 0.

Variable selection was achieved by dropping fixed (Kery and Schaub 2011, 77–82) variables with two-sided p-values \(\geq\) 0.05 (Kery and Schaub 2011, 37, 42) and random variables with percent relative errors \(\geq\) 80%.

The results are displayed graphically by plotting the modeled relationships between particular variables and the response with 80% or 95% credible intervals (CIs) with the remaining variables held constant. In general, continuous and discrete fixed variables are held constant at their mean and first level values respectively while random variables are held constant at their typical values (expected values of the underlying hyperdistributions) (Kery and Schaub 2011, 77–82). Where informative the influence of particular variables is expressed in terms of the effect size (i.e., percent change in the response variable) with 95% CIs (Bradford, Korman, and Higgins 2005).

Model Descriptions

Model Templates

Abundance

  data {

    int<lower=0> nMarked;
    int<lower=0> Marked[nMarked];
    int<lower=0> Resighted[nMarked];
    int<lower=0> IndexMarked[nMarked];

    int<lower=0> nObs;
    int Marking[nObs];
    int Index[nObs];
    int<lower=0> nSwimmer;
    int<lower=0> Swimmer[nObs];
    int<lower=0> nYear;
    int<lower=0> Year[nObs];
    real Width[nObs];
    real Rkm[nObs];
    int<lower=0> nSite;
    int<lower=0> Site[nObs];

    real SiteLength[nObs];
    real SurveyProportion[nObs];

    int Count[nObs];
  }
  parameters {
    real bEfficiency;
    real bEfficiencyIndex;

    real bDensity;
    vector[nYear] bDensityYear;
    real bDensityWidth;
    vector[4] bDensityRkm;
    real<lower=0> sDensitySite;
    vector[nSite] bDensitySite;

    real bEfficiencyMarking;
    real bEfficiencyMarkingIndex;

    real<lower=0,upper=5> sEfficiencySwimmer;
    vector[nSwimmer] bEfficiencySwimmer;

    real<lower=0> sDispersion;
  }
  model {

    vector[nObs] eDensity;
    vector[nObs] eEfficiency;
    vector[nObs] eAbundance;
    vector[nObs] eCount;

    sDispersion ~ gamma(0.01, 0.01);

    bDensity ~ normal(0, 2);
    bDensityRkm ~ normal(0, 2);
    sDensitySite ~ uniform(0, 5);
    bDensitySite ~ normal(0, sDensitySite);
    bDensityWidth ~ normal(0, 2);
    bDensityYear ~ normal(0, 5);

    bEfficiency ~ normal(0, 5);
    bEfficiencyIndex ~ normal(0, 5);
    bEfficiencyMarking ~ normal(0, 5);
    bEfficiencyMarkingIndex ~ normal(0, 5);
    sEfficiencySwimmer ~ uniform(0, 5);
    bEfficiencySwimmer ~ normal(0, sEfficiencySwimmer);

    for (i in 1:nMarked) {
      target += binomial_lpmf(Resighted[i] | Marked[i],
        inv_logit(
          bEfficiency +
          bEfficiencyIndex * IndexMarked[i] +
          bEfficiencyMarking +
          bEfficiencyMarkingIndex * IndexMarked[i]
        ));
    }

    for (i in 1:nObs) {
      eDensity[i] = exp(bDensity +
                        bDensityRkm[1] * Rkm[i] +
                        bDensityRkm[2] * pow(Rkm[i], 2.0) +
                        bDensityRkm[3] * pow(Rkm[i], 3.0) +
                        bDensityRkm[4] * pow(Rkm[i], 4.0) +
                        bDensitySite[Site[i]] +
                        bDensityYear[Year[i]] +
                        bDensityWidth * log(Width[i]));

      eEfficiency[i] = inv_logit(
        bEfficiency +
        bEfficiencyIndex * Index[i] +
        bEfficiencyMarking * Marking[i] +
        bEfficiencyMarkingIndex * Index[i] * Marking[i] +
        bEfficiencySwimmer[Swimmer[i]]);

      eAbundance[i] = eDensity[i] * SiteLength[i];

      eCount[i] = eAbundance[i] * eEfficiency[i] * SurveyProportion[i];
    }

    target += neg_binomial_2_lpmf(Count | eCount, sDispersion);
  }

Template 1. Abundance model description.

Condition

 data {
  int nYear;
  int nObs;

  vector[nObs] Length;
  vector[nObs] Weight;
  int Year[nObs];

parameters {
  real bWeight;
  real bWeightLength;
  real sWeightYear;

  vector[nYear] bWeightYear;
  real sWeight;

model {

  vector[nObs] eWeight;

  bWeight ~ normal(-10, 5);
  bWeightLength ~ normal(3, 2);

  sWeightYear ~ normal(-2, 5);

  for (i in 1:nYear) {
    bWeightYear[i] ~ normal(0, exp(sWeightYear));
  }

  sWeight ~ normal(-2, 5);
  for(i in 1:nObs) {
    eWeight[i] = bWeight + bWeightLength * log(Length[i]) + bWeightYear[Year[i]];
    Weight[i] ~ lognormal(eWeight[i], exp(sWeight));
  }
..

Template 2.

Fecundity

 data {
  int nObs;

  vector[nObs] Weight;
  vector[nObs] Fecundity;

parameters {
  real bFecundity;
  real bFecundityWeight;
  real sFecundity;

model {

  vector[nObs] eFecundity;

  bFecundity ~ uniform(0, 5);
  bFecundityWeight ~ uniform(0, 2);

  sFecundity ~ uniform(0, 1);
  for(i in 1:nObs) {
    eFecundity[i] = log(bFecundity) + bFecundityWeight * log(Weight[i]);
    Fecundity[i] ~ lognormal(eFecundity[i], sFecundity);
  }
..

Template 3.

Stock-Recruitment

model {
  a ~ dunif(0, 1)
  b ~ dunif(0, 0.1)
  sScaling ~ dunif(0, 5)

  eRecruits <- a * Stock / (1 + Stock * b)

  for(i in 1:nObs) {
    esRecruits[i] <- SDLogRecruits[i] * sScaling
    Recruits[i] ~ dlnorm(log(eRecruits[i]), esRecruits[i]^-2)
  }
..

Template 4. Stock-Recruitment model description.

Tables

Abundance

Condition

Fecundity

Egg Deposition

Stock-Recruitment

Figures

Length Correction

Abundance

Condition

Fecundity

Spawner Size

Egg Deposition

Stock-Recruitment

Environmental

Reproductive Rate

Recommendations

• Develop a Limit Reference Point that ensures a effective population size (\(N_e\)) of 500.
• Develop an Upper Reference Point that ensures adequate Kokanee recruitment.