Lower Columbia River Fish Population Indexing Analysis 2015

Condition

The expected weight of fish of a given length were estimated from the data using a mass-length model (He et al. 2008). Key assumptions of the condition model include:

• The expected weight is allowed to vary with length and date.
• The expected weight is allowed to vary randomly with year.
• The relationship between weight and length is allowed to vary with date.
• The relationship between weight and length is allowed to vary randomly with year.
• The residual variation in weight is log-normally distributed.

Only previously untagged fish were included in models to avoid potential effects of tagging on body condition. Preliminary analyses indicated that the annual variation in weight was not correlated with the annual variation in the relationship between weight and length.

Growth

Annual growth of fish were estimated from the inter-annual recaptures using the Fabens method (Fabens 1965) for estimating the von Bertalanffy growth curve (von Bertalanffy 1938). This curve is based on the premise that:

\[ \frac{\text{d}L}{\text{d}t} = k (L_{\infty} - L)\]

where \(L\) is the length of the individual, \(k\) is the growth coefficient and \(L_{\infty}\) is the mean maximum length.

Integrating the above equation gives:

\[ L_t = L_{\infty} (1 - e^{-k(t - t_0)})\]

where \(L_t\) is the length at time \(t\) and \(t_0\) is the time at which the individual would have had no length.

The Fabens form allows

\[ L_r = L_c + (L_{\infty} - L_c) (1 - e^{-kT})\]

where \(L_r\) is the length at recapture, \(L_c\) is the length at capture and \(T\) is the time between capture and recapture.

Key assumptions of the growth model include:

• The mean maximum length \(L_{\infty}\) is constant.
• The growth coefficient \(k\) is allowed to vary randomly with year.
• The residual variation in growth is normally distributed.

Length-At-Age

The expected length-at-age of Mountain Whitefish and Rainbow Trout were estimated from annual length-frequency distributions using a finite mixture distribution model (Macdonald and Pitcher 1979). Key assumptions of the length-at-age model include:

• There are three distinguishable age-classes for each species: Age-0, Age-1 and Age-2+.
• The proportion of fish in each age-class is allowed to vary randomly with year.
• The expected growth between age-classes is allowed to vary with age-class.
• The expected growth between age-classes is allowed to vary randomly with age-class within year.
• The expected length increases with age-class.
• The expected length is allowed to vary with year within age-class.
• The expected length is allowed to vary as a second-order polynomial with date.
• The relationship between length and date is allowed to vary randomly with age-class.
• The residual variation in length is normally distributed.
• The standard deviation of this normal distribution is allowed to vary randomly with age-class.

The model was used to estimate the cut-offs between age-classes by year. For the purposes of estimating other population parameters by age-class, Age-0 individuals were classified as fry, Age-1 individuals were classified as subadult, and Age-2+ individuals were classified as adult. Walleye could not be separated by life stage due to a lack of discrete modes in the length-frequency distributions for this species. Consequently, all captured Walleye were considered to be adults.

The results include plots of the age-class density for each year by length as predicted by the length-at-age model. Density is a measure of relative frequency for continuous values.

Observer Length Correction

The bias (accuracy) and error (precision) in observer’s fish length estimates were quantified using a model with a categorical distribution which compared the proportions of fish in different length-classes for each observer to the equivalent proportions for the measured fish. Key assumptions of the observer length correction model include:

• The proportion of fish in each length-class is allowed to vary with year.
• The expected length bias is allowed to vary with observer.
• The expected length error is allowed to vary with observer.
• The expected length bias and error for a given observer does not vary by year.
• The residual variation in length is normally distributed.

The observed fish lengths were corrected for the estimated length biases before being classified as fry, subadult and adult based on the length-at-age cutoffs.

Survival

The annual adult survival rate was estimated by fitting a Cormack-Jolly-Seber model (Kery and Schaub 2011, 220–31) to inter-annual recaptures of adults.

Key assumptions of the survival model include:

• Survival varies randomly with year.
• The encounter probability for adults is allowed to vary with the total bank length sampled.

Site Fidelity

The extent to which sites are closed, i.e., fish remain at the same site between sessions, was evaluated with a logistic ANCOVA (Kery 2010). The model estimates the probability that intra-annual recaptures were caught at the same site versus a different one. Key assumptions of the site fidelity model include:

• The expected site fidelity is allowed to vary with fish length.
• Observed site fidelity is Bernoulli distributed.

Length as a second-order polynomial was not found to be a significant predictor for site fidelity.

Capture Efficiency

The probability of capture was estimated using a recapture-based binomial model (Kery and Schaub 2011, 134–36, 384–88).

Key assumptions of the capture efficiency model include:

• The capture probability varies randomly by session within year.
• The probability of a marked fish remaining at a site is the estimated site fidelity.
• The number of recaptures is described by a binomial distribution.

Abundance

The abundance was estimated from the catch and bias-corrected observer count data using an overdispersed Poisson model (Kery and Schaub 2011, 55–56). The model assumed that the capture efficiency was the mean estimate from the capture efficiency model and that the number of observed fish was a multiple of the number of captured fish. The annual abundance estimates represent the total number of fish in the study area.

Key assumptions of the abundance model include:

• The capture efficiency is the mean estimate from the capture efficiency model.
• The observer efficiency varies from the capture efficiency.
• The lineal fish density varies randomly with site, year and site within year.
• The catches and counts are described by a Poisson-gamma distribution.

The annual distribution of each species was calculated using the Shannon index of evenness (\(E\)) where \(S\) was the number of sites and \(p_i\) the proportion of the population belonging to the \(i\)^th site.

\[ E = \frac{-\sum p_i \log(p_i)}{ln(S)}\]

Long-Term Trends

Trends common to the fish index and environmental annual time series were identified using dynamic factor analysis (DFA) (Zuur, Tuck, and Bailey 2003) – a dimension-reduction technique designed for time-series data.

The fish index time series were the condition (Con), growth (Grw) length-at-age (Len), survival (Sur) and Abundance (Abn) by species (MW = Mountain Whitefish, RB = Rainbow Trout, WP = Walleye) and life stage (Sub = Subadult, Ad = Adult) or age (Age0, Age1).

The environmental time series were the mean (DisMe) and average hourly absolute difference (DisDi) in discharge at Birchbank, the average water temperature (TemMe) at Norns Creek by quarterly period, the Pacific Decadal Oscillation Index (PDO), the Ephemeroptera, Plecoptera, Trichoptera and Dipterans in the Lower Columbia River (EPT), the biomass of zooplankton in Arrow Lakes Reservoir (ZOO) and the annual proportional egg loss through dewatering (Regime) by species (MW = Mountain Whitefish, RB = Rainbow Trout).

The average hourly absolute discharge difference was calculated by differencing the mean hourly discharge time series and taking the average of the absolute differences. Mathematically this is equivalent to: \[ \frac{\sum |x_{1}-x_{2}| + |x_{2}-x_{3}| + ... + |x_{n-1}-x_{n}|}{n-1} \] where \(x_{1}\) is the discharge at the start of the time series and \(x_{2}\) is the discharge an hour later.

The October to December times series were lead by one year to account for the fact that they occurred after sampling and are expected to only influence the fish time series in the following year. Similarly, the Mountain Whitefish egg loss time series were also lead by one year to account for the fact that they flow changes mostly occur the following year. If \(\geq\) 10% of the discharge or temperature data were missing for a three-month period the value was not included in the time series.

All time series were standardized prior to fitting the DFA model. Key assumptions of the model include:

• The time series are described by six underlying trends.
• The random walk processes in the trends are normally distributed.
• The residual variation in the standardised variables is normally distributed.

Due to the rotation problem the underlying trends were indeterminate (Abmann, Boysen-Hogrefe, and Pape 2014). The similarities were represented visually by using non-metric multidimensional scaling (NMDS) to cluster the time series based on the absolute values of the dynamic factor analysis trend weightings.

Short-Term Correlations

To assess the short-term congruence between the yearly fish metrics and the environmental variables, the pair-wise distances between the residuals from the DFA model were calculated as \(1 - |\rho(x, y)|\) where \(\rho\) is the Pearson correlation and \(x\) and \(y\) are the two time series being compared.

The short-term similarities were represented visually by using NMDS to cluster the time series based on the pair-wise distances.

Scale Age

The age of Mountain Whitefish was estimated from scales by two independent agers. The scale aging process was repeated twice per ager, leading to two observations per ager per fish encounter (Hurlbert 1984). Individuals that could be aged at initial capture based on their length using the length-at-age model with a certainty \(\geq 0.95\) were assigned a known hatch year. Otherwise the hatch year was estimated by the model from the scale ages. The scale ages were analysed using a state-space linear mixed model that assigned an age to each fish based on the year of capture and its hatch year.

Key assumptions of the scale age model include:

• The actual age is the year of capture minus the hatch year
• The scale age varies by ager.
• The scale age varies randomly with fish encounter and ager within fish encounter.
• The scale age varies linearly with age.
• The effect of age on scale age varies by ager.
• The random effects are normally distributed.
• The residual variation in the scale ages (replicate within ager within encounter) is described by a zero-truncated normal distribution.

Age-Ratios

The proportion of Age-1 Mountain Whitefish \(r^1_t\) from a given spawn year \(t\) is calculated from the number of Age-1 and Age-2 fish \(N^1_t\) and \(N^2_t\) respectively, which were lead or lagged so that all values were with respect to the spawn year:

\[r^1_t = \frac{N^1_{t+2}}{N^1_{t+2} + N^2_{t+2}}\]

As the number of Age-2 fish might be expected to be influenced by the percentage egg loss \(Q_t\) three years prior, the predictor variable \(\Pi_t\) used is:

\[\Pi_t = \textrm{log}(Q_t/Q_{t-1})\]

The ratio was logged to ensure it was symmetrical about zero (Tornqvist, Vartia, and Vartia 1985). The ages from the scale age model were corrected by subtracting one.

The relationship between \(r^1_t\) and \(\Pi_t\) was estimated using a hierarchical Bayesian logistic regression (Kery 2010) loss model.

Key assumptions of the final model include:

• The log odds of the proportion of Age-1 fish varies linearly with the log of the ratio of the percent egg losses.
• The numbers of Age-1 fish are extra-Binomially distributed.

The relationship between percent dewatering and subsequent recruitment is expected to depend on stock abundance (Subbey et al. 2014) which might be changing over the course of the study. Consequently, preliminary analyses allowed the slope of the regression line to change by year. However, year was not a significant predictor and was therefore removed from the final model. The effect of dewatering on Mountain Whitefish abundance was expressed in terms of the predicted percent change in Age-1 Mountain Whitefish abundance by egg loss in the spawn year relative to 10% egg loss in the spawn year. The egg loss in the previous year was fixed at 10%. The percent change could not be calculated relative to 0% in the spawn or previous year as \(\Pi_t\) is undefined in either case.

Stock-Recruitment

The relationship between the adults and the resultant number of age-1 subadultswas estimated using a Bayesian Beverton-Holt stock-recruitment model (Walters and Martell 2004):

\[ R = \frac{\alpha \cdot S}{1 + \beta \cdot S} \quad,\]

where \(S\) is the adults (stock), \(R\) is the subadults (recruits), \(\alpha\) is the recruits per spawner at low density and \(\beta\) determines the density-dependence.

Key assumptions of the stock-recruitment model include:

• The prior probability for \(\alpha\) is a uniform distribution from 0 to 5.
• The density-dependence varies with the proportional egg loss.
• The residual variation in the number of recruits is log-normally distributed.

The carrying capacity \(K\) is given by the relationship:

\[ K = \frac{\alpha}{\beta} \quad.\]

Condition

model {

  bWeight ~ dnorm(5, 5^-2)
  bWeightLength ~ dnorm(3, 2^-2)

  bWeightDayte ~ dnorm(0, 2^-2)
  bWeightLengthDayte ~ dnorm(0, 2^-2)

  sWeightYear ~ dunif(0, 1)
  sWeightLengthYear ~ dunif(0, 1)
  for (i in 1:nYear) {
    bWeightYear[i] ~ dnorm(0, sWeightYear^-2)
    bWeightLengthYear[i] ~ dnorm(0, sWeightLengthYear^-2)
  }

  sWeight ~ dunif(0, 1)
  for(i in 1:length(Length)) {
    eLogWeight[i] <-    bWeight
                      + bWeightDayte * Dayte[i]
                      + bWeightYear[Year[i]]
                      + ( bWeightLength
                        + bWeightLengthDayte * Dayte[i]
                        + bWeightLengthYear[Year[i]]
                        ) * Length[i]

    Weight[i] ~ dlnorm(eLogWeight[i], sWeight^-2)
  }
}

Growth

model {

  bK ~ dnorm (0, 5^-2)
  sKYear ~ dunif (0, 5)
  for (i in 1:nYear) {
    bKYear[i] ~ dnorm(0, sKYear^-2)
    log(eK[i]) <- bK + bKYear[i]
  }

  bLinf ~ dunif(100, 1000)
  sGrowth ~ dunif(0, 100)

  for (i in 1:length(Year)) {
    eGrowth[i] <- (bLinf - LengthAtRelease[i]) * (1 - exp(-sum(eK[Year[i]:(Year[i] + Years[i] - 1)])))

    Growth[i] ~ dnorm(eGrowth[i], sGrowth^-2)
  }
}

Length-At-Age

model{

  for(ii in 1:nAge){
    bGrowthAge[ii] ~ dunif(10, 100)
    sGrowthAgeYear[ii] ~ dunif(0, 25)
    for(jj in 1:nYear) {
      bGrowthAgeYear[ii, jj] ~ dnorm(0, sGrowthAgeYear[ii]^-2)
      eGrowthAgeYear[ii, jj] <- bGrowthAge[ii] + bGrowthAgeYear[ii, jj]
    }
  }

  bLengthAgeYear[1, 1] <- eGrowthAgeYear[1, 1]
  for(ii in 2:nAge){
    bLengthAgeYear[ii, 1] <- bLengthAgeYear[ii-1, 1] - bGrowthAgeYear[ii-1, 1] + eGrowthAgeYear[ii, 1]
  }

  for(jj in 2:nYear){
    bLengthAgeYear[1, jj] <- eGrowthAgeYear[1, jj]
    for(ii in 2:nAge){
      bLengthAgeYear[ii, jj] <- bLengthAgeYear[ii-1, jj-1] + eGrowthAgeYear[ii, jj]
    }
  }

  for(ii in 1:nAge)  {
    bDayte[ii] ~ dnorm(0, 10)
    bDayte2[ii] ~ dnorm(0, 10)
  }

  sAgeYear ~ dunif(0, 5)
  for(ii in 1:(nAge - 1)){
    bAge[ii] ~ dnorm(0, 2^-2)
    for(jj in 1:nYear){
      bAgeYear[ii, jj] ~ dnorm(0, sAgeYear^-2)
    }
  }

  for(jj in 1:nYear){
    logit(pAgeYear[1, jj]) <- bAge[1] + bAgeYear[1, jj]
    for(ii in 2:(nAge - 1)){
      pAgeYear[ii, jj] <- (1 - sum(pAgeYear[1:(ii - 1), jj])) * ilogit(bAge[ii] + bAgeYear[ii, jj])
    }
    pAgeYear[nAge, jj] <- (1 - sum(pAgeYear[1:(nAge - 1), jj]))
  }

    for(ii in 1:nAge){
    sLengthAge[ii] ~ dunif(0, 50)
  }

    for(ii in 1:length(Length)){
    Age[ii] ~ dcat(pAgeYear[1:nAge, Year[ii]])
    eLength[ii] <-  bLengthAgeYear[Age[ii], Year[ii]]
                  + bDayte[Age[ii]] * Dayte[ii]
                  + bDayte2[Age[ii]] * Dayte[ii]^2
    Length[ii] ~ dnorm(eLength[ii], sLengthAge[Age[ii]]^-2)
  }
}

Observer Length Correction

model{

  for(j in 1:nYear){
    for(i in 1:nClass) {
      dClass[i, j] <- 1
    }
    pClass[1:nClass, j] ~ ddirch(dClass[, j])
  }

  bLength[1] <- 1
  sLength[1] <- 1

  for(i in 2:nObserver) {
    bLength[i] ~ dunif(0.5, 2)
    sLength[i] ~ dunif(2, 10)
  }

  for(i in 1:length(Length)){
    eClass[i] ~ dcat(pClass[, Year[i]])
    eLength[i] <- bLength[Observer[i]] * ClassLength[eClass[i]]
    eSLength[i] <- sLength[Observer[i]] * ClassSD
    Length[i] ~ dnorm(eLength[i], eSLength[i]^-2)
  }
}

Survival

model{
  bEfficiency ~ dnorm(0, 5^-2)
  bEfficiencySampledLength ~ dnorm(0, 5^-2)

  bSurvival ~ dnorm(0, 5^-2)

  sSurvivalYear ~ dunif(0, 5)
  for(i in 1:nYear) {
    bSurvivalYear[i] ~ dnorm(0, sSurvivalYear^-2)
  }

  for(i in 1:(nYear-1)) {
    logit(eEfficiency[i]) <- bEfficiency + bEfficiencySampledLength * SampledLength[i]
    logit(eSurvival[i]) <- bSurvival + bSurvivalYear[i]

    eProbability[i,i] <- eSurvival[i] * eEfficiency[i]
    for(j in (i+1):(nYear-1)) {
      eProbability[i,j] <- prod(eSurvival[i:j]) * prod(1-eEfficiency[i:(j-1)]) * eEfficiency[j]
    }
    for(j in 1:(i-1)) {
      eProbability[i,j] <- 0
    }
  }
  for(i in 1:(nYear-1)) {
    eProbability[i,nYear] <- 1 - sum(eProbability[i,1:(nYear-1)])
  }

  for(i in 1:(nYear - 1)) {
    Marray[i, 1:nYear] ~ dmulti(eProbability[i,], Released[i])
  }
}

Site Fidelity

model {

  bFidelity ~ dnorm(0, 2^-2)
  bLength ~ dnorm(0, 2^-2)

  for (i in 1:length(Fidelity)) {
    logit(eFidelity[i]) <- bFidelity + bLength * Length[i]
    Fidelity[i] ~ dbern(eFidelity[i])
  }
}

Capture Efficiency

model {

  bEfficiency ~ dnorm(0, 5^-2)

  sEfficiencySessionYear ~ dunif(0, 2)
  for (i in 1:nSession) {
    for (j in 1:nYear) {
      bEfficiencySessionYear[i, j] ~ dnorm(0, sEfficiencySessionYear^-2)
    }
  }

  for (i in 1:length(Recaptures)) {

    logit(eEfficiency[i]) <- bEfficiency + bEfficiencySessionYear[Session[i], Year[i]]

    eFidelity[i] ~ dnorm(Fidelity[i], FidelitySD[i]^-2) T(0, 1)
    Recaptures[i] ~ dbin(eEfficiency[i] * eFidelity[i], Tagged[i])
  }
}

Abundance

model {
  bDensity ~ dnorm(5, 5^-2)

  bVisitType[1] <- 1
  for (i in 2:nVisitType) {
    bVisitType[i] ~ dunif(0, 10)
  }

  sDensityYear ~ dunif(0, 2)
  for (i in 1:nYear) {
    bDensityYear[i] ~ dnorm(0, sDensityYear^-2)
  }

  sDensitySite ~ dunif(0, 2)
  sDensitySiteYear ~ dunif(0, 2)
  for (i in 1:nSite) {
    bDensitySite[i] ~ dnorm(0, sDensitySite^-2)
    for (j in 1:nYear) {
      bDensitySiteYear[i, j] ~ dnorm(0, sDensitySiteYear^-2)
    }
  }

  sDispersion ~ dunif(0, 5)
  for (i in 1:length(Fish)) {
    log(eDensity[i]) <- bDensity + bDensitySite[Site[i]] + bDensityYear[Year[i]] + bDensitySiteYear[Site[i],Year[i]]

    eDispersion[i] ~ dgamma(1 / sDispersion^2, 1 / sDispersion^2)
    Fish[i] ~ dpois(eDensity[i] * SiteLength[i] * ProportionSampled[i] * Efficiency[i] * bVisitType[VisitType[i]] * eDispersion[i])
  }
}

Long-Term Trends

model{

  sTrend ~ dunif(0, 1)
  for (t in 1:nTrend) {
    bTrendYear[t,1] ~ dunif(-1,1)
    for(y in 2:nYear){
      bTrendYear[t,y] ~ dnorm(bTrendYear[t,y-1], sTrend^-2)
    }
  }

  for(v in 1:nVariable){
    for(t in 1:nTrend) {
      Z[v,t] ~ dunif(-1,1)
    }
    for(y in 1:nYear){
      eValue[v,y,1] <- Z[v,1] * bTrendYear[1,y]
      for(t in 2:nTrend) {
        eValue[v,y,t] <- eValue[v,y,t-1] + Z[v,t] * bTrendYear[t,y]
      }
    }
  }

  sValue ~ dunif(0, 1)
  for(i in 1:length(Value)) {
    Value[i] ~ dnorm(eValue[Variable[i], Year[i], nTrend], sValue^-2)
  }

  for(i in 1:nVariable) {
    for(j in 1:nVariable) {
      bDistance[i,j] <- sqrt(sum((Z[i,]-Z[j,])^2))
    }
  }
}

Scale Age

model {
  for(i in 1:nBirthYear) {
    dYear[i] <- 1
  }
  pYear ~ ddirch(dYear[])
  for(i in 1:nFishID){
    BirthYear[i] ~ dcat(pYear)
  }
  mBirthYear <- BirthYear
  bIntercept <- 0
  bSlope <- 1
  for(i in 1:nAger) {
    sSD[i] ~ dunif(0, 5)
  }
  for(i in 1:nAger) {
    bInterceptAger[i] ~ dnorm(0, 2^-2)
    bSlopeAger[i] ~ dnorm(0, 2^-2)
  }
  sInterceptEncounterID ~ dunif(0, 2)
  sInterceptEncounterIDAger ~ dunif(0, 2)
  for(i in 1:nEncounterID) {
    bInterceptEncounterID[i] ~ dnorm(0, sInterceptEncounterID^-2)
    for(j in 1:nAger) {
      bInterceptEncounterIDAger[i,j] ~ dnorm(0, sInterceptEncounterIDAger^-2)
    }
  }
  for(i in 1:length(ScaleAge)){
    eAge[i] <- Year[i] - BirthYear[FishID[i]]
    eScaleAge[i] <- bIntercept + bInterceptAger[Ager[i]] + (bSlope + bSlopeAger[Ager[i]]) * eAge[i] + bInterceptEncounterID[EncounterID[i]] + bInterceptEncounterIDAger[EncounterID[i], Ager[i]]
    ScaleAge[i] ~ dnorm(eScaleAge[i], sSD[Ager[i]]^-2) T(0,)
  }
}

Age-Ratios

model{

  bProbAge1 ~ dnorm(0, 1000^-2)
  bProbAge1Loss ~ dnorm(0, 1000^-2)

  sDispersion ~ dunif(0, 1000)
  for(i in 1:length(LossLogRatio)){
    eDispersion[i] ~ dnorm(0, sDispersion^-2)
    logit(eProbAge1[i]) <- bProbAge1 + bProbAge1Loss * LossLogRatio[i] + eDispersion[i]
    Age1[i] ~ dbin(eProbAge1[i], Age1and2[i])
  }
}

Stock-Recruitment

model {

  bAlpha ~ dunif(0, 5)
  bBeta ~ dunif(0, 1)
  bBetaEggLoss ~ dnorm(0, 2^-2)

  sRecruits ~ dunif(0, 5)
  for(i in 1:length(Stock)){
    log(eBeta[i]) <- log(bBeta) + bBetaEggLoss * EggLoss[i]
    eRecruits[i] <- (bAlpha * Stock[i]) / (1 + eBeta[i] * Stock[i])
    Recruits[i] ~ dlnorm(log(eRecruits[i]), sRecruits^-2)
  }
}

Condition - Mountain Whitefish

Condition - Rainbow Trout

Condition - Walleye

Growth - Mountain Whitefish

Growth - Rainbow Trout

Growth - Walleye

Length-At-Age - Mountain Whitefish

Length-At-Age - Rainbow Trout

Observer Length Correction - Mountain Whitefish

Observer Length Correction - Rainbow Trout

Observer Length Correction - Walleye

Survival - Mountain Whitefish

Survival - Rainbow Trout

Survival - Walleye

Site Fidelity - Mountain Whitefish

Site Fidelity - Rainbow Trout

Site Fidelity - Walleye

Capture Efficiency - Mountain Whitefish - Subadult

Capture Efficiency - Mountain Whitefish - Adult

Capture Efficiency - Rainbow Trout - Subadult

Capture Efficiency - Rainbow Trout - Adult

Capture Efficiency - Walleye - Adult

Abundance - Mountain Whitefish - Subadult

Abundance - Mountain Whitefish - Adult

Abundance - Rainbow Trout - Subadult

Abundance - Rainbow Trout - Adult

Abundance - Walleye - Adult

Long-Term Trends

Scale Age

Age-Ratios

Stock-Recruitment - Mountain Whitefish

Stock-Recruitment - Rainbow Trout

Condition

Condition - Mountain Whitefish - Subadult

Condition - Mountain Whitefish - Adult

Condition - Rainbow Trout - Subadult

Condition - Rainbow Trout - Adult

Condition - Walleye - Adult

Growth

Growth - Mountain Whitefish

Growth - Rainbow Trout

Growth - Walleye

Length-At-Age - Mountain Whitefish

Length-At-Age - Mountain Whitefish - Age-0

Length-At-Age - Mountain Whitefish - Age-1

Length-At-Age - Rainbow Trout

Length-At-Age - Rainbow Trout - Age-0

Length-At-Age - Rainbow Trout - Age-1

Observer Length Correction

Survival - Mountain Whitefish - Adult

Survival - Rainbow Trout - Adult

Survival - Walleye - Adult

Site Fidelity

Capture Efficiency

Capture Efficiency - Mountain Whitefish - Subadult

Capture Efficiency - Mountain Whitefish - Adult

Capture Efficiency - Rainbow Trout - Subadult

Capture Efficiency - Rainbow Trout - Adult

Capture Efficiency - Walleye - Adult

Abundance

Abundance - Mountain Whitefish - Subadult

Abundance - Mountain Whitefish - Adult

Abundance - Rainbow Trout - Subadult

Abundance - Rainbow Trout - Adult

Abundance - Walleye - Adult

Long-Term Trends

Short-Term Correlations

Scale Age

Age-Ratios

Stock-Recruitment - Mountain Whitefish

Stock-Recruitment - Rainbow Trout