Lower Columbia River Fish Population Indexing 2023

Discharge

Missing hourly discharge values for Hugh-Keenleyside Dam (HLK), Brilliant Dam (BRD) and Birchbank (BIR) were estimated by first leading the BIR values by 2 hours to account for the lag. Values missing at just one of the dams were then estimated assuming \(HLK + BRD = BIR\). Negative values were set to be zero. Next, missing values spanning \(\leq\) 28 days were estimated at HLK and BRD based on linear interpolation. Finally any remaining missing values at BIR were set to be \(HLK + BRD\).

Condition

The expected weight of fish of a given length were estimated from the data using an allometric mass-length model (He et al. 2008).

\[W = \alpha L^{\beta}\]

Key assumptions of the condition model include:

• The expected weight is allowed to vary with length and date.
• The expected weight is allowed to vary randomly with year.
• The relationship between weight and length is allowed to vary with date.
• The relationship between weight and length is allowed to vary randomly with year.
• The residual variation in weight is log-skew-normally distributed.

Only previously untagged fish were included in models to avoid potential effects of tagging on body condition. Preliminary analyses indicated that the annual variation in weight was not correlated with the annual variation in the relationship between weight and length.

Growth

Annual growth of fish were estimated from the inter-annual recaptures using the Fabens method (Fabens 1965) for estimating the von Bertalanffy growth curve (von Bertalanffy 1938). This curve is based on the premise that:

\[ \frac{\text{d}L}{\text{d}t} = k (L_{\infty} - L)\]

where \(L\) is the length of the individual, \(k\) is the growth coefficient and \(L_{\infty}\) is the maximum length.

Integrating the above equation gives:

\[ L_t = L_{\infty} (1 - e^{-k(t - t_0)})\]

where \(L_t\) is the length at time \(t\) and \(t_0\) is the time at which the individual would have had zero length.

The Fabens form allows

\[ L_r = L_c + (L_{\infty} - L_c) (1 - e^{-kT})\]

where \(L_r\) is the length at recapture, \(L_c\) is the length at capture and \(T\) is the time between capture and recapture.

Key assumptions of the growth model include:

• The mean maximum length \(L_{\infty}\) is constant.
• The growth coefficient \(k\) is allowed to vary randomly with year.
• The residual variation in growth is normally distributed.

The growth model was only fitted to Walleye with a fork length at release less than 450 mm.

Site Fidelity

The extent to which sites are closed, i.e., fish remain at the same site between sessions, was evaluated with a logistic ANCOVA (Kery 2010). The model estimates the probability that intra-annual recaptures were caught at the same site versus a different one. Key assumptions of the site fidelity model include:

• The expected site fidelity is allowed to vary with fish length.
• Observed site fidelity is Bernoulli distributed.

Length as a second-order polynomial was not found to be a significant predictor for site fidelity.

The estimated probability of being caught at the same site versus a different site was then converted into the site fidelity by assuming that those fish which were recaught at a different site represented just 32 % of those that left the site. The correction factor corresponds to the proportion of the river bank that belongs to index sites.

Observer Length Correction

The annual bias (inaccuracy) and error (imprecision) in observer’s fish length estimates were quantified from the divergence of the length distribution of their observed fish from the length distribution of the measured fish. More specifically, the length correction that minimized the Jensen-Shannon divergence (Lin 1991) between the two distributions provided a measure of the inaccuracy while the minimum divergence (the Jensen-Shannon divergence was calculated with log to base 2 which means it lies between 0 and 1) provided a measure of the imprecision.

Length-At-Age

The expected length-at-age of Mountain Whitefish and Rainbow Trout were estimated from annual length-frequency distributions using a finite mixture distribution model (Macdonald and Pitcher 1979).

There were assumed to be three distinguishable normally-distributed age-classes for Mountain Whitefish (Age-0, Age-1, Age-2 and Age-3+) two for Rainbow Trout (Age-0, Age-1, Age-2+). Initially the model was fitted to the data from all years combined. The model was then fitted to the data for each year separately with the initial values set to be the estimates from the combined values. The only constraints were that the standard deviations of the MW age-classes were identical in the combined analysis and fixed at the initial values in the individual years. Models which did not converge were excluded and the length cutoff was calculated based on linear interpolation of the estimates for the neighboring years.

Rainbow Trout and Mountain Whitefish were categorized as Fry (Age-0), Juvenile (Age-1) and Adult (Age-2+) based on their length-based ages. All Walleye were considered to be Adults.

Survival

The annual adult survival rate was estimated by fitting a Cormack-Jolly-Seber model (Kery and Schaub 2011, 220–31) to inter-annual recaptures of adults.

Key assumptions of the survival model include:

• Survival varies randomly with year.
• The encounter probability for adults is allowed to vary with the total bank length sampled.

Preliminary analysis indicated that only including visits to index sites did not substantially change the results.

Recapture Efficiency

The probability of recapture was estimated using a recapture-based binomial model (Kery and Schaub 2011, 134–36, 384–88).

Key assumptions of the recapture efficiency model include:

• The recapture probability varies randomly by session within year.
• The number of recaptures is described by a binomial distribution.

Preliminary analyses indicated that the direction of effect of the frequency of the electrofishing current (30, 60 or 120 Hz) was uncertain.

Abundance

The abundance was estimated from the catch and bias-corrected observer count data using an overdispersed Poisson model (Kery and Schaub 2011, 55–56).

Key assumptions of the abundance model include:

• The fish density varies randomly with site, year and site within year.
• The capture efficiency at a typical fish density is the recapture efficiency in a typical session divided by the site fidelity.
• The count efficiency varies from the capture efficiency.
• The overdispersion varies by visit type (count or catch).
• The catches and counts are described by a gamma-Poisson distribution.

Survival (Abundance-based)

The subadult (\(S_t\)) and adult (\(A_t\)) abundance estimates were used to calculate the subadult and adult survival (\(\phi_t\)) in year \(t\) based on the relationship

\[\phi_t = \frac{A_t}{S_{t-1} + A_{t-1}}\]

Weight

The weight (\(W_t\)) in year \(t\) was estimated using the condition model from the expected adult length from the length-at-age model.

Fecundity

Egg Deposition

The total egg deposition (\(E_t\)) in year t was calculated from the estimated fecundity (\(F_t\)) and adult abundance (\(A_t\)), assuming that the population was 50% female according to the equation \[E_t = F_t * \frac{A_t}{2}\]

Stock-Recruitment

The relationship between the total number of eggs deposited (\(E_t\)) and the resultant number of subadults (age-1 recruits) (\(S_{t+1}\)) was estimated using a Beverton-Holt stock-recruitment model (Walters and Martell 2004):

\[S_{t+1} = \frac{\alpha \cdot E_t}{1 + \beta \cdot E_t}\]

where \(\alpha\) is the egg to age-1 survival at low density and \(\beta\) is the density-dependence.

Key assumptions of the stock-recruitment model include:

• The egg to recruit survival at low density (\(\alpha\)) was likely less than 1% (the prior distribution for \(\alpha\) was a zero truncated normal with standard deviation of 0.003.
• The expected log number of recruits varies with the proportional egg loss.
• The residual variation in the number of recruits is log-normally distributed.

The expected egg survival for a given egg deposition is \(S / E_t\) which is given by the equation

\[\phi_E = \frac{\alpha}{1 + \beta * E}\]

Age-Ratios

The proportion of Age-1 Mountain Whitefish \(r^1_t\) from a given spawn year \(t\) is calculated from the proportion of Age-1 & Age-2 fish \(P^1_t\) & \(P^2_t\) respectively in the length-at-age analysis, which were lead or lagged so that all values were with respect to the spawn year:

\[r^1_t = \frac{P^1_{t+2}}{P^1_{t+2} + P^2_{t+2}}\]

As the proportion of Age-2 fish might be expected to be influenced by the percentage egg loss \(Q_t\) three years prior, the predictor variable \(\Pi_t\) used is:

\[\Pi_t = \textrm{log}(Q_t/Q_{t-1})\]

The ratio was logged to ensure it was symmetrical about zero (Tornqvist et al. 1985).

The relationship between \(r^1_t\) and \(\Pi_t\) was estimated using a Bayesian regression (Kery 2010) loss model.

Key assumptions of the final model include:

• The log odds of the proportion of Age-1 fish varies with the log of the ratio of the percent egg losses.
• The residual variation is normally distributed.

The relationship between percent dewatering and subsequent recruitment is expected to depend on stock abundance (Subbey et al. 2014) which might be changing over the course of the study. Consequently, preliminary analyses allowed the slope of the regression line to change by year. However, year was not a significant predictor and was therefore removed from the final model. The effect of dewatering on Mountain Whitefish abundance was expressed in terms of the predicted percent change in Age-1 Mountain Whitefish abundance by egg loss in the spawn year relative to 10% egg loss in the spawn year. The egg loss in the previous year was fixed at 10%. The percent change could not be calculated relative to 0% in the spawn or previous year as \(\Pi_t\) is undefined in either case.

Adjusted Recruitment

The abundance of Age-1 Rainbow Trout was estimated based on the proportion of the Rainbow Trout eggs dewatered the previous year and the abundance of age-1 Mountain Whitefish caught in the same year to account for inter-annual variation in age-1 salmonid abundance and/or capture efficiency.

The relationship(s) were estimated using a Generalized Linear Model (GLM).

Key assumptions of the final model include:

• The abundance of Age-1 Rainbow Trout varies with proportion of the eggs dewatered and then number of Age-1 Mountain Whitefish caught in the same year.
• The residual variation is log-normally distributed.

Condition

 data {
  int nYear;
  int nObs;

  vector[nObs] Length;
  vector[nObs] Weight;
  vector[nObs] Dayte;
  int Year[nObs];

parameters {
  real bWeight;
  real bWeightLength;
  real bWeightDayte;
  real bWeightLengthDayte;
  real<lower=0> sWeightYear;
  real<lower=0> sWeightLengthYear;

  vector[nYear] bWeightYear;
  vector[nYear] bWeightLengthYear;
  real bShape;
  real<lower=0> sWeight;

model {

  vector[nObs] eWeight;
  vector[nObs] eMu;

  bWeight ~ normal(5, 4);
  bWeightLength ~ normal(3, 1);

  bWeightDayte ~ normal(0, 1);
  bWeightLengthDayte ~ normal(0, 1);

  sWeightYear ~ normal(0, 1);
  sWeightLengthYear ~ normal(0, 1);

  for (i in 1:nYear) {
    bWeightYear[i] ~ normal(0, sWeightYear);
    bWeightLengthYear[i] ~ normal(0, sWeightLengthYear);
  }

  sWeight ~ normal(0, 5);
  bShape ~ normal(0, 2);
  for(i in 1:nObs) {
    eWeight[i] = exp(bWeight + bWeightDayte * Dayte[i] + bWeightYear[Year[i]] + (bWeightLength + bWeightLengthDayte * Dayte[i] + bWeightLengthYear[Year[i]]) * Length[i]);
    eMu[i] <- eWeight[i] - sWeight * (bShape / sqrt(1 + bShape^2)) * sqrt(2 / pi());
    log(Weight[i]) ~ skew_normal(log(eMu[i]), sWeight, bShape);
  }

Block 1. Model description.

Growth

.model {
  bK ~ dnorm (0, 5^-2)
  sKYear ~ dnorm(0, 2^-2) T(0,)

  for (i in 1:nYear) {
    bKYear[i] ~ dnorm(0, sKYear^-2)
    log(eK[i]) <- bK + bKYear[i]
  }

  bLinf ~ dunif(200, 1000)
  sGrowth ~ dnorm(0, 25^-2) T(0,)
  for (i in 1:length(Year)) {
    eGrowth[i] <- max(0, (bLinf - LengthAtRelease[i]) * (1 - exp(-sum(eK[Year[i]:(Year[i] + dYears[i] - 1)]))))
    Growth[i] ~ dnorm(eGrowth[i], sGrowth^-2)
  }

Block 2.

Site Fidelity

.model {

  bFidelity ~ dnorm(0, 1^-2)
  bLength ~ dnorm(0, 1^-2)

  for (i in 1:length(Fidelity)) {
    logit(eFidelity[i]) <- bFidelity + bLength * Length[i]
    Fidelity[i] ~ dbern(eFidelity[i])
  }

Block 3.

Survival

.model{
  bEfficiency ~ dnorm(-3, 2^-2)
  bEfficiencySampledLength ~ dnorm(0, 1^-2)

  bSurvival ~ dnorm(0, 2^-2)

  sSurvivalYear ~ dnorm(0, 2^-2) T(0,)
  for(i in 1:nYear) {
    bSurvivalYear[i] ~ dnorm(0, sSurvivalYear^-2)
  }

  for(i in 1:(nYear-1)) {
    logit(eEfficiency[i]) <- bEfficiency + bEfficiencySampledLength * SampledLength[i]
    logit(eSurvival[i]) <- bSurvival + bSurvivalYear[i]

    eProbability[i,i] <- eSurvival[i] * eEfficiency[i]
    for(j in (i+1):(nYear-1)) {
      eProbability[i,j] <- prod(eSurvival[i:j]) * prod(1-eEfficiency[i:(j-1)]) * eEfficiency[j]
    }
    for(j in 1:(i-1)) {
      eProbability[i,j] <- 0
    }
  }
  for(i in 1:(nYear-1)) {
    eProbability[i,nYear] <- 1 - sum(eProbability[i,1:(nYear-1)])
  }

  for(i in 1:(nYear - 1)) {
    Marray[i, 1:nYear] ~ dmulti(eProbability[i,], Released[i])
  }

  for (i in 1:(nYear - 1)) {
    for (j in 1:nYear) {
      eMarray[i, j] <- Released[i] * eProbability[i, j]
      eOrg[i, j] <- pow((pow(Marray[i, j], 0.5) - pow(eMarray[i, j], 0.5)), 2)
    }
  }

  # Generate replicate data and compute fit stats from them
  for (i in 1:(nYear - 1)) {
    eMarray2[i, 1:nYear] ~ dmulti(eProbability[i, ], Released[i])
    for (j in 1:nYear) {
      eNew[i, j] <- pow((pow(eMarray2[i, j], 0.5) - pow(eMarray[i, j], 0.5)), 2)
    }
  }
  bFit <- sum(eOrg[, ])
  bFitNew <- sum(eNew[, ])

Block 4.

Recapture Efficiency

data {
  int<lower=1> nObs;
  int<lower=1> nAnnual;
  int<lower=1> nSession;

  int <lower=0> Recaptures[nObs];
  int <lower=0> Tagged[nObs];
  int <lower=1> Annual[nObs];
  int <lower=1> Session[nObs];

parameters {
  real bEfficiency;

  real <lower = 0> sEfficiencyAnnualSession;
  matrix[nAnnual,nSession] bEfficiencyAnnualSession;

model {
  vector[nObs] eEfficiency;

  bEfficiency ~ normal(-5, 2);
  sEfficiencyAnnualSession ~ normal(0, 1);

  for(i in 1:nAnnual) {
    bEfficiencyAnnualSession[i,] ~ normal(0, sEfficiencyAnnualSession);
  }

  for (i in 1:nObs) {
    eEfficiency[i] = inv_logit(bEfficiency + bEfficiencyAnnualSession[Annual[i],Session[i]]);

    Recaptures[i] ~ binomial(Tagged[i], eEfficiency[i]);
  }

Block 5.

Abundance

.model {
  bDensity ~ dnorm(5, 4^-2)

  sDensityAnnual ~ dnorm(0, 1^-2) T(0,)
  for (i in 1:nAnnual) {
    bDensityAnnual[i] ~ dnorm(0, sDensityAnnual^-2)
  }

  sDensitySite ~ dnorm(0, 1^-2) T(0,)
  sDensitySiteAnnual ~ dnorm(0, 1^-2) T(0,)
  for (i in 1:nSite) {
    bDensitySite[i] ~ dnorm(0, sDensitySite^-2)
    for (j in 1:nAnnual) {
      bDensitySiteAnnual[i, j] ~ dnorm(0, sDensitySiteAnnual^-2)
    }
  }

  bEfficiencyVisitType[1] <- 0
  for (i in 2:nVisitType) {
    bEfficiencyVisitType[i] ~ dnorm(0, 2^-2)
  }

  for(i in 1:nVisitType) {
    sDispersionVisitType[i] ~ dnorm(0, 2^-2) T(0,)
  }

  bEfficiency ~ dnorm(Efficiency, EfficiencySD^2) T(EfficiencyLower, EfficiencyUpper)
  bFidelity ~ dnorm(Fidelity, FidelitySD^2) T(FidelityLower, FidelityUpper)

  for (i in 1:length(Fish)) {
    log(eDensity[i]) <- bDensity + bDensitySite[Site[i]] + bDensityAnnual[Annual[i]] + bDensitySiteAnnual[Site[i],Annual[i]]

    eAbundance[i] <- eDensity[i] * SiteLength[i]

    logit(eEfficiency[i]) <- logit(bEfficiency/ bFidelity) + bEfficiencyVisitType[VisitType[i]]

    eFish[i] <- eAbundance[i] * ProportionSampled[i] * eEfficiency[i]

    eDispersion[i] ~ dgamma(sDispersionVisitType[VisitType[i]]^-2, sDispersionVisitType[VisitType[i]]^-2)
    Fish[i] ~ dpois(eFish[i] * eDispersion[i])
  }

Block 6.

Fecundity

model {
  bFecundity ~ dnorm(0, 5^-2)
  bFecundityWeight ~ dnorm(1, 1^-2) T(0,)

  sFecundity ~ dnorm(0, 1^-2) T(0,)
  for(i in 1:length(Weight)) {
    eFecundity[i] = bFecundity + bFecundityWeight * log(Weight[i])
    Fecundity[i] ~ dlnorm(eFecundity[i], sFecundity^-2)
  }

Block 7.

Stock-Recruitment

.model {
  bAlpha ~ dnorm(0, 0.003^-2) T(0,)
  bBeta ~ dnorm(0, 0.007^-2) T(0, )
  bEggLoss ~ dnorm(0, 100^-2)

  sRecruits ~ dnorm(0, 1^-2) T(0,)
  for(i in 1:length(Recruits)){
    log(eRecruits[i]) <- log(bAlpha * Eggs[i] / (1 + bBeta * Eggs[i])) + bEggLoss * EggLoss[i]
    Recruits[i] ~ dlnorm(log(eRecruits[i]), sRecruits^-2)
  }

Block 8.

Age-Ratios

.model{
  bProbAge1 ~ dnorm(0, 1^-2)
  bProbAge1Loss ~ dnorm(0, 1^-2)

  sProbAge1 ~ dnorm(0, 1^-2) T(0,)
  for(i in 1:length(Age1Prop)){
    eAge1Prop[i] <- bProbAge1 + bProbAge1Loss * LossLogRatio[i]
    Age1Prop[i] ~ dnorm(eAge1Prop[i], sProbAge1^-2)
  }

Block 9.

Adjusted Recruitment

.model{
  b0 ~ dnorm(0, 10^-2)
  bMw ~ dnorm(0, 2^-2)
  bEggLoss ~ dnorm(0, 2^-2)

  sRb ~ dnorm(0, 2^-2) T(0,)
  for (i in 1:nObs) {
    log(eRb[i]) <- b0 + bMw * Mw[i] + bEggLoss * EggLoss[i]
    Rb[i] ~ dlnorm(log(eRb[i]), sRb^-2)
  }

Block 10. Model description.

Condition

Table 1. Parameter descriptions.

Growth

Table 14. Parameter descriptions.

Site Fidelity

Table 27. Parameter descriptions.

Length-At-Age

Survival

Table 42. Parameter descriptions.

Recapture Efficiency

Table 55. Parameter descriptions.

Abundance

Table 76. Parameter descriptions.

Fecundity

Table 97. Parameter descriptions.

Stock-Recruitment

Table 102. Parameter descriptions.

Age-Ratios

Table 111. Parameter descriptions.

Table 112. Model coefficients.

Table 113. Model summary.

Table 114. Model posterior predictive checks.

Table 115. Model sensitivity.

Adjusted Recruitment

Table 116. Parameter descriptions.

Table 117. Model coefficients.

Table 118. Model convergence.

Table 119. Model posterior predictive checks.

Table 120. Model sensitivity.

Condition

Subadult

Mountain Whitefish

Rainbow Trout

Adult

Mountain Whitefish

Rainbow Trout

Walleye

Growth

Mountain Whitefish

Rainbow Trout

Walleye

Site Fidelity

Observer Length Correction

Length-At-Age

Mountain Whitefish

Rainbow Trout

Survival

Adult

Mountain Whitefish

Rainbow Trout

Walleye

Recapture Efficiency

Mountain Whitefish

Subadult

Adult

Rainbow Trout

Subadult

Adult

Walleye

Abundance

Mountain Whitefish

Subadult

Adult

Rainbow Trout

Subadult

Adult

Walleye

Survival (Abundance-based)

Mountain Whitefish

Rainbow Trout

Weight

Mountain Whitefish

Rainbow Trout

Fecundity

Mountain Whitefish

Rainbow Trout

Egg Deposition

Mountain Whitefish

Rainbow Trout

Stock-Recruitment

Mountain Whitefish

Rainbow Trout

Age-Ratios

Adjusted Recruitment