Llgaay Gwii sdiihlda (Restoring Balance project) 2014-2019

Model

The data were analysed using a power function (Ward et al. 2013) for the relationship between efficiency and density

\[\text{Efficiency} = \alpha \cdot {\text{Density}}^{\beta} \]

Four models were considered which varied in whether they included variation in \(\alpha\) and \(\beta\) by method.

Key assumptions of all the models include:

• There is no migration among the islands during the course of the study.
• The relationship between efficiency and density is described by a power function.
• The expected number of deer removed by island, method and day is the product of the efficiency and effort.
• The residual variation in the number deer removed by island, method and day is described by an overdispersed Poisson distribution (negative binomial).

The full model (variation in \(\alpha\) and \(\beta\) by method = ambm) is defined algebraically as follows:

\[\text{Efficiency}_{m,i,d} = \alpha_{m} \cdot {\text{Density}_{i,d}}^{\beta_{m}} \] where \(\text{Efficiency}_{m,i,d}\) is the efficiency of the \(m\)th method on the \(i\)th island during the \(d\)th day, \(\alpha_{m}\) is the efficiency of the \(m\)th method at a density of 1 deer per km², \(\text{Density}_{i,d}\) is the deer density (deer/km²) on the \(i\)th island at the start of the \(d\)th day and \(\beta_{m}\) is the scaling constant.

The allometric coefficient and the scaling exponent in the power function are given by

\[\log(\alpha_{m}) = a_m \] and

\[\log(\beta_{m}) = b_m\]

, respectively, where \(a_m\) and \(b_m\) are the values by method.

The expected number of deer removed using the \(m\)th method on the \(i\)th island during the \(d\)th day (\(\mu_{m,i,d}\)) is given by

\[\lambda_{m,i,d} = \text{Efficiency}_{m,i,d} \cdot \text{Effort}_{m,i,d}\]

where \(\text{Effort}_{m,i,d}\) is the effort (heli hours) of the \(m\)th method on the \(i\)th island during the \(d\)th day.

The actual number of deer removed using the \(m\)th method on the \(i\)th island during the \(d\)th day (\(\mu_{m,i,d}\)) is given by the relationship

\[\text{Removed}_{m,i,d} \sim \text{NBinomial}(\lambda_{m,i,d}, \phi)\]

The total population on each island at the start of the study was given by

\[\text{Population}_{i} = \text{TotalRemoved}_i + \Psi_i\]

where \(\Psi_i\), which is the total number of remaining deer on the \(i\)th island, was based on the number of scent trails detected by dogs at the end of the surveys and the effective coverage of those dogs according to the relationship

\[\text{ScentTrails}_i \sim \text{Binomial}(\Psi_{i},\text{Coverage}_i)\]

The priors were as follows:

\[a_m \sim \text{Normal}(1, 2)\]

\[b_m \sim \text{Normal}(0, 2)\] \[\phi \sim \text{Normal}(0, 1)\ \text{T}(0,)\]

\[\Psi_i \sim \text{Normal}(0, \text{Area}_i \cdot 5) \text{T}(0,)\]

Removal

model{
  for(i in 1:nIsland) {
    bRemaining[i] ~ dnorm(0, (5 * Area[i])^-2) T(0,)
    Detections[i] ~ dbin(ObsEff[i], round(bRemaining[i]))
    bPopn[i,1] <- round(TotalRemoved[i] + bRemaining[i])
    bDensity[i,1] <- bPopn[i,1] / Area[i]
    for(j in 2:nDay) { 
      bPopn[i,j] <- bPopn[i,j-1] - DeerTotal[i,j-1]
      bDensity[i,j] <- bPopn[i,j] / Area[i]
    }
  }
  alpha0 <- 0

  for(i in 1:nMethod) {
    alpha_method[i] ~ dnorm(1, 2^-2)
  }

  beta0 <- 0

  for(i in 1:nMethod) {
    beta_method[i] ~ dnorm(0, 2^-2)
  }

  phi ~ dnorm(0, 1^-2) T(0,)
  for(i in 1:nObs) {
    eDensity[i] <- bDensity[Island[i],Day[i]]
    eEffort[i] <- Hours[i] * HourlyRate[i]
    log(eAlpha[i]) <- alpha0 + alpha_method[Method[i]]
    log(eBeta[i]) <- beta0 + beta_method[Method[i]]
    log(eEfficiency[i]) <- eAlpha[i] +  log((eDensity[i] / 100)^eBeta[i])
    eDeer[i] <- eEffort[i] * eEfficiency[i] 
    eR[i] <- 1/phi
    eP[i] <- eR[i] / (eR[i] + eDeer[i])
    Deer[i] ~ dnegbin(eP[i], eR[i])
  }

Block 1. Model description.

Costs

Table 1. The estimated hourly costs (in $) by crew member and equipment.

Removal

Table 2. The number of scent trail detections by dogs and the effective coverage by island.

Table 3. Model comparison using Pareto Smoothed Importance-Sampling Leave-One-Out Cross-Validation (PSIS) criterion. ‘ic’ is the information criterion value (IC) on the deviance scale; ‘se’ is the standard error of the IC; ‘npars’ is the number of effective parameters, ‘delta ic’ is the difference between the model’s IC and the minimum IC; ‘delta se’ is the standard error of the difference in IC; ‘weight’ summarizes the relative support for each model; and ‘k outliers’ is the proportion of data points with Pareto \(\hat{k}\) values exceeding 0.7.

Table 4. Parameter descriptions.

Table 5. Model terms (with 95% CIs).

Table 6. Model convergence.

Table 7. Model sensitivity.

Table 8. Model sensitivity by parameter.

Table 9. Model sensitivity by fixed terms.

Table 10. Model posterior predictive checks.

Table 11. The total number of deer removed, the area (km2) and the removal density (deer/km2) by island.

Table 12. The total number of deer removed and the estimated number of remaining deer by island (with CIs).

Table 13. The total number of deer removed and the estimated percent eradication completion by island (with CIs).

Table 14. The total costs spent in heli hours by island.

Table 15. The estimated total completion cost by island and method (with CIs).

Table 16. The estimated proportional efficiency of indicator dog hunting by method and density.

Table 17. The total number of deer removed and the proportion of the encounters removed by method.

Table 18. The total number of deer removed on Ramsay Island and the proportion of the encounters removed by method.

Removal